REM WLG WeatherLink Guard por MolinoMeteo
REM
REM Este script batch arranca Weatherlink y detecta cuelgues
REM WeatherLink debe estar configurado para enviar plantillas Meteoclimatic
REM WLG compara la plantilla actual con la de 5 minutos antes
REM (se supone que el Weatherlink la está actualizando cada 1 o 2 minutos)
REM Si la plantilla no ha cambiado se supone que el WeatherLink está colgado
REM En ese caso se mata el proceso y se rearranca de nuevo
REM Se registra en el log cada rearranque del WeatherLink
REM También se registra cada nuevo arranque del script WLG
REM Así también queda constancia de los apagones
REM
REM Quien use este script lo hace por su cuenta y riesgo
REM El autor no se hace responsable de ningún perjuicio ocasionado por su uso
REM
REM Preparativos:
REM    Colocar este script batch WLG.bat en el directorio Templates de la estacion
REM    (por ejemplo: C:\Archivos de programa\WeatherLink\MolinoMe\Templates)
REM    Quitar el acceso directo a Weatherlink de Inicio y poner uno a WLG.BAT
REM    Modificar las 2 variables (lineas SET que van al comienzo del script)
REM    para que apunten a los directorios y ejecutable correctos


SET DirWL="C:\WeatherLink"
SET WL="WeatherLink57.exe"

REM Registra en el log el arranque del script
ECHO %date% %time% Arrancando script >> WLG.log

REM Arranca el Weatherlink (si no está arrancado ya)
TASKLIST /FI "IMAGENAME eq Weatherlink*" /FO CSV > busqueda.log
FOR /F %%A IN (busqueda.log) DO IF %%~zA EQU 0 GOTO ARRANCADO
ECHO %date% %time% Arrancando Weatherlink >> WLG.log
START "" /D%DirWL% %WL%
:ARRANCADO
DEL busqueda.log

REM Inicializa la copia de la plantilla para las comparaciones
COPY meteoclimatic.htm meteoclimatic_viejo.htm

:EMPEZAR

   REM Espera 5 minutos
   PING 1.0.0.0 -n 1 -w 300000

   REM Compara la plantilla vieja de hace cinco minutos con la actual
   ECHO n|COMP meteoclimatic.htm meteoclimatic_viejo.htm
   IF NOT ERRORLEVEL 1 GOTO IGUALES
   
   :DIFERENTES
   REM La plantilla ha cambiado
   REM Todo OK, se actualiza la plantilla vieja y vuelta a empezar
   COPY meteoclimatic.htm meteoclimatic_viejo.htm
   GOTO EMPEZAR
 
   :IGUALES
   REM La plantilla no ha cambiado en 5 minutos
   REM Se supone que WeatherLink se ha colgado. 
   REM Se anota en el log , se cierra WL, se rearranca y vuelta a empezar
   ECHO %date% %time% Cerrando y rearrancando WeatherLink >> WLG.log
   TASKKILL /F /IM "Weatherlink*" /T
   PING 1.0.0.0 -n 1 -w 30000
   START "" /D%DirWL% %WL%
   GOTO EMPEZAR